创建具有 List 的应用程序

1. 创建一个新的 Flash 文件 (ActionScript 3.0) 文档。
2. 将一个 List 组件从"组件"面板拖到舞台上。
3. 在"属性"检查器中，执行以下操作：
   • 输入实例名称 aList。
   • 将值 200 分配给 W（宽）。
4. 使用"文本"工具在 aList 下方创建一个文本字段，并为它指定实例名称 aTf。
5. 打开"动作"面板，在主时间轴中选择第 1 帧，然后输入以下 ActionScript 代码：

   import fl.controls.List;
   import flash.text.TextField;
   
   aTf.type = TextFieldType.DYNAMIC;
   aTf.border = false;
   
   // Create these items in the Property inspector when data and label
   // parameters are available.
   aList.addItem({label:"1956 Chevy (Cherry Red)", data:35000});
   aList.addItem({label:"1966 Mustang (Classic)", data:27000});
   aList.addItem({label:"1976 Volvo (Xcllnt Cond)", data:17000});
   aList.allowMultipleSelection = true;
   
   aList.addEventListener(Event.CHANGE, showData);
   
   function showData(event:Event) {
       aTf.text = "This car is priced at: $" + event.target.selectedItem.data;
   }
   

   此代码使用 addItem() 方法，用三个项来填充 aList，为每一项分配一个 label 值（该值将出现在列表中）和一个 data 值。当您在列表中选择某一项时，事件侦听器将调用 showData() 函数，该函数会显示所选项的 data 值。

6. 选择"控制">"测试影片"来编译并运行此应用程序。

下面的示例还创建一个由汽车型号及其价格组成的 List。不过，该示例使用数据提供者，而不是 addItem() 方法来填充此 List。

1. 创建一个新的 Flash 文件 (ActionScript 3.0) 文档。
2. 将一个 List 组件从"组件"面板拖到舞台上。
3. 在"属性"检查器中，执行以下操作：
   • 输入实例名称 aList。
   • 将值 200 分配给 W（宽）。
4. 使用"文本"工具在 aList 下方创建一个文本字段，并为它指定实例名称 aTf。
5. 打开"动作"面板，在主时间轴中选择第 1 帧，然后输入以下 ActionScript 代码：

   import fl.controls.List;
   import fl.data.DataProvider;
   import flash.text.TextField;
   
   aTf.type = TextFieldType.DYNAMIC;
   aTf.border = false;
   
   var cars:Array = [
   {label:"1956 Chevy (Cherry Red)", data:35000},
   {label:"1966 Mustang (Classic)", data:27000},
   {label:"1976 Volvo (Xcllnt Cond)", data:17000},
   ];
   aList.dataProvider = new DataProvider(cars);
   aList.allowMultipleSelection = true;
   
   aList.addEventListener(Event.CHANGE, showData);
   
   function showData(event:Event) {
       aTf.text = "This car is priced at: $" + event.target.selectedItem.data;
   }
   

6. 选择"控制">"测试影片"，以查看此 List 及其项。

下面的示例创建一个由颜色名称组成的 List，当您选择某种颜色时，它将该颜色应用于影片剪辑。

1. 创建一个 Flash 文件 (ActionScript 3.0) 文档。
2. 将一个 List 组件从"组件"面板拖到舞台上，并在"属性"检查器中为该组件指定以下值：
   • 输入 aList 作为实例名称。
   • 输入 60 作为 H 值。
   • 输入 100 作为 X 值。
   • 输入 150 作为 Y 值。
3. 打开"动作"面板，在主时间轴中选择第 1 帧，然后输入以下 ActionScript 代码：

   aList.addItem({label:"Blue", data:0x0000CC});
   aList.addItem({label:"Green", data:0x00CC00});
   aList.addItem({label:"Yellow", data:0xFFFF00});
   aList.addItem({label:"Orange", data:0xFF6600});
   aList.addItem({label:"Black", data:0x000000});
   
   var aBox:MovieClip = new MovieClip();
   addChild(aBox);
   
   aList.addEventListener(Event.CHANGE, changeHandler);
   function changeHandler(event:Event) {
       drawBox(aBox, event.target.selectedItem.data);
   };
   
   function drawBox(box:MovieClip,color:uint):void {
               box.graphics.beginFill(color, 1.0);
               box.graphics.drawRect(225, 150, 100, 100);
               box.graphics.endFill();        
   }
   

4. 选择"控制">"测试影片"，运行应用程序。
5. 单击此 List 中的颜色，可以看到颜色会显示在影片剪辑中。

下面的示例使用 ActionScript 创建一个简单列表，并使用 addItem() 方法填充该列表。

1. 创建一个新的 Flash 文件 (ActionScript 3.0) 文档。
2. 将一个 List 组件从"组件"面板拖到"库"面板中。
3. 打开"动作"面板，在主时间轴中选择第 1 帧，然后输入以下 ActionScript 代码：

   import fl.controls.List;
   
   var aList:List = new List();
   aList.addItem({label:"One", data:1});
   aList.addItem({label:"Two", data:2});
   aList.addItem({label:"Three", data:3});
   aList.addItem({label:"Four", data:4});
   aList.addItem({label:"Five", data:5});
   aList.setSize(60, 40);
   aList.move(200,200);
   addChild(aList);
   aList.addEventListener(Event.CHANGE, changeHandler);
   function changeHandler(event:Event):void {
       trace(event.target.selectedItem.data);
   }
   

4. 选择"控制">"测试影片"，运行应用程序。