创建具有 CheckBox 组件的应用程序

以下过程解释了如何在创作时将 CheckBox 组件添加到应用程序，本示例摘自一个贷款申请表。该申请表询问申请人是否拥有自己的住房，并为申请人提供了一个 CheckBox 来回答"是"。如果是，则申请表将为申请人显示两个单选按钮，以表示房屋的相对价值。

创建具有 CheckBox 组件的应用程序：

创建一个新的 Flash 文件 (ActionScript 3.0) 文档。
将一个 CheckBox 组件从"组件"面板拖到舞台上。
在"属性"检查器中，执行以下操作：
- 输入 homeCh 作为实例名称。
- 输入 140 作为宽度 (W) 值。
- 输入"Own your home?"作为 label 参数。
将两个 RadioButton 组件从"组件"面板拖到舞台上，并将它们分别放在 CheckBox 的下面和右侧。在"属性"检查器中为它们输入以下值：
- 输入 underRb 和 overRb 作为实例名称。
- 输入 120 作为两个单选按钮的 W（宽）参数。
- 输入"Under $500,000?"作为 underRb 的 label 参数。
- 输入"Over $500,000?"作为 overRb 的 label 参数。
- 输入 valueGrp 作为两个单选按钮的 groupName 参数。
打开"动作"面板，在主时间轴中选择第 1 帧，然后输入以下 ActionScript 代码：
```
homeCh.addEventListener(MouseEvent.CLICK, clickHandler);
underRb.enabled = false;
overRb.enabled = false;

function clickHandler(event:MouseEvent):void {
    underRb.enabled = event.target.selected;
    overRb.enabled = event.target.selected;      
}
```
此代码为 click 事件创建一个事件处理函数，如果选中 homeCh 复选框，则该函数启用 underRb 和 overRb 单选按钮，如果未选中 homeCh，则禁用这两个单选按钮。有关详细信息，请参阅《ActionScript 3.0 语言和组件参考》中的 MouseEvent 类。
选择"控制">"测试影片"。

以下示例重复了上述应用，但采用 ActionScript 来创建 CheckBox 和 RadioButton 组件。

使用 ActionScript 创建 CheckBox：

创建一个新的 Flash 文件 (ActionScript 3.0) 文档。
将 CheckBox 组件和 RadioButton 组件从"组件"面板拖到当前文档的"库"面板中。如果"库"面板没有打开，请按 Ctrl+L 或选择"窗口">"库"以打开"库"面板。
此操作使组件可用于应用程序，但不会将它们放在舞台上。

打开"动作"面板，在主时间轴中选择第 1 帧，然后输入以下代码创建并放置组件实例：

import fl.controls.CheckBox;
import fl.controls.RadioButton;

var homeCh:CheckBox = new CheckBox();
var underRb:RadioButton = new RadioButton();
var overRb:RadioButton = new RadioButton();
addChild(homeCh);
addChild(underRb);
addChild(overRb);
underRb.groupName = "valueGrp";
overRb.groupName = "valueGrp";
homeCh.move(200, 100);
homeCh.width = 120;
homeCh.label = "Own your home?";
underRb.move(220, 130);
underRb.enabled = false;
underRb.width = 120;
underRb.label = "Under $500,000?";
overRb.move(220, 150);
overRb.enabled = false;
overRb.width = 120;
overRb.label = "Over $500,000?";

此代码使用 CheckBox() 和 RadioButton() 构造函数创建组件，并使用 addChild() 方法将组件放在舞台上。然后，使用 move() 方法确定组件在舞台上的位置。

现在，添加以下 ActionScript 来创建一个事件侦听器和一个事件处理函数：
```
homeCh.addEventListener(MouseEvent.CLICK, clickHandler);

function clickHandler(event:MouseEvent):void {
    underRb.enabled = event.target.selected;
    overRb.enabled = event.target.selected;      
}
```
此代码为 click 事件创建一个事件处理函数，如果选中 homeCh CheckBox，则该函数启用 underRb 和 overRb 单选按钮，如果未选中 homeCh，则禁用这两个单选按钮。有关详细信息，请参阅《ActionScript 3.0 语言和组件参考》中的 MouseEvent 类。
选择"控制">"测试影片"。