大括号

1. 选择"文件">"新建"，然后选择"ActionScript 文件"。
2. 选择"文件">"另存为"，将此新文档另存为 Student.as。
3. 将以下 ActionScript 添加到该 AS 文件中。

   // Student.as
   class Student {
       private var _id:String;
       private var _firstName:String;
       private var _middleName:String;
       private var _lastName:String;
   
       public function Student(id:String, firstName:String, middleName:String, lastName:String) {
           this._id = id;
           this._firstName = firstName;
           this._middleName = middleName;
           this._lastName = lastName;
       }
       public function get firstName():String {
           return this._firstName;
       }
       public function set firstName(value:String):Void {
           this._firstName = value;
       }
       // ...
   }
   

4. 保存该类文件。
5. 选择"文件">"新建"，然后单击"Flash 文档"创建一个新的 FLA 文件。
6. 将该新的 FLA 文件另存为 student_test.fla。
7. 在主时间轴的第 1 帧上键入下面的 ActionScript：

   // student_test.fla
   import Student;
   var firstStudent:Student = new Student("cst94121", "John", "H.", "Doe");
   trace(firstStudent.firstName); // John
   firstStudent.firstName = "Craig";
   trace(firstStudent.firstName); // Craig
   

8. 选择"文件">"保存"以保存对 student_test.fla 所做的更改。
9. 选择"控制">"测试影片"对 FLA 和 AS 文件进行测试。

下一个示例演示了使用函数时如何使用大括号。

1. 选择"文件">"新建"，然后选择"Flash 文档"创建一个新的 FLA 文件。
2. 选择"文件">"另存为"，将此新文件命名为 checkform.fla。
3. 将 Label 组件的实例从"组件"面板拖到舞台上。
4. 打开"属性"检查器（"窗口">"属性">"属性"），选择该 Label 组件实例，然后在"实例名称"文本框中键入实例名称 status_lbl。
5. 在 W（宽度）文本框中键入 200 将该组件的大小调整为 200 像素宽。
6. 将 TextInput 组件的实例拖到舞台上，然后为它指定实例名称 firstName_ti。
7. 将 Button 组件的实例拖到舞台上，然后为它指定实例名称 submit_button。
8. 选择时间轴中的第 1 帧，在"动作"面板中，添加下面的 ActionScript：

   function checkForm():Boolean {
       status_lbl.text = "";
       if (firstName_ti.text.length == 0) {
           status_lbl.text = "Please enter a first name.";
           return false;
       }
       return true;
   }
   function clickListener(evt_obj:Object):Void {
       var success:Boolean = checkForm();
   };
   submit_button.addEventListener("click", clickListener);
   

9. 选择"文件">"保存"以保存该 Flash 文档。
10. 选择"控制">"测试影片"，在创作环境中对代码进行测试。

    在 SWF 文件中，如果在 firstName_ti TextInput 组件中没有加入文本时就单击舞台上的 Button 实例，就会显示一条错误消息。该错误消息出现在 Label 组件中，告知用户他们需要输入名字。

下一个示例使用大括号显示了如何在对象内创建和定义属性。在此例中，属性在对象中是通过在大括号 ({}) 标点符号中指定变量名称来定义的：

var myObject:Object = {id:"cst94121", firstName:"John", middleName:"H.", lastName:"Doe"};
var i:String;
for (i in myObject) {
    trace(i + ": " + myObject[i]);
}
/*
    ID：cst94121
    名字：John
    中间名：H.
    姓氏：Doe
*/

还可以使用空的大括号对作为 new Object() 函数的语法快捷方式。例如，以下代码将创建一个空的 Object 实例：

var myObject:Object = {};