使用 ActionScript 绘制 Accordion 标题

import mx.skins.RectBorder;
import mx.core.ext.UIObjectExtensions;

class RedGreenBlueHeader extends RectBorder
{
 static var symbolName_str:String = "RedGreenBlueHeader";
 static var symbolOwner_obj:Object = RedGreenBlueHeader;
 
 function size():Void
 {
  var color_num:Number; // 颜色
  var borderStyle_str:String = getStyle("borderStyle"); // Accordion 的属性

  // 定义每种选项卡状态下 Accordion 中的每个选项卡的颜色。
  switch (borderStyle_str) {
   case "falseup":
   case "falserollover":
   case "falsedisabled":
    color_num = 0x7777FF;
    break;
   case "falsedown":
    color_num = 0x77FF77;    
    break;
   case "trueup":
   case "truedown":
   case "truerollover":
   case "truedisabled":
    color_num = 0xFF7777;
    break;
  }

  // 清除默认样式并绘制自定义样式。
  clear();
  lineStyle(0, 0, 100);
  beginFill(color_num, 100);
  drawRect(0, 0, __width, __height);
  endFill();
 }
 
 // 外观所需内容
 static function classConstruct():Boolean
 {
  UIObjectExtensions.Extensions();
  _global.skinRegistry["AccordionHeaderSkin"] = true;
  return true;
 }
 static var classConstructed_bl:Boolean = classConstruct();
 static var UIObjectExtensionsDependency_obj:Object = UIObjectExtensions;
}